feature(neon): since nixos-hardware was added, add support for the t14g1 as well

Reviewed-on: #85

.git-blame-ignore-revs

@@ -0,0 +1,2 @@
+# nixfmt reformat
+2231d2fc3fb4dc140c5f3257523dcdb513ac4dea

.gitignore

@@ -8,3 +8,7 @@ result-*
 
 # vim
 *.swp
+
+# devenv
+.devenv*
+devenv.local.nix

INSTALLATION.md

@@ -2,8 +2,13 @@
 
 - The installations presented in this repository are always luks encrypted
 - For simplicity I'm using device labels rather than uuids
+- Secure Boot has to be disabled in the firmware, the installer iso isn't signed
 
-1. the partitioning layout should look somewhat like this after the installation
+1. create the partitions with `cfdisk` or `fdisk` (gpt)
+   - `nvme0n1p1`: 2G, type `EFI System`, otherwise the firmware won't find the bootloader
+   - `nvme0n1p2`: the rest, type `Linux filesystem`
+
+   the layout should look somewhat like this after the installation
 ```bash
 NAME               MAJ:MIN RM   SIZE RO TYPE  MOUNTPOINTS
 nvme0n1            259:0    0 476.9G  0 disk
@@ -30,12 +35,13 @@ cryptsetup luksOpen /dev/nvme0n1p2 cryptroot
 pvcreate /dev/mapper/cryptroot
 # create a volume group inside
 vgcreate lvmroot /dev/mapper/cryptroot
-# create the swap volume
-lvcreate --size 8G lvmroot --name swap
+# create the swap volume, half the ram (no hibernation)
+lvcreate --size 16G lvmroot --name swap
 # if you desire, create a home volume
 lvcreate --size 150G lvmroot --name home
-# create the root volume
-lvcreate -l 100%FREE lvmroot --name root
+# create the root volume, leave some space in the vg to grow volumes later
+# (lvextend -r -L +50G lvmroot/home works while mounted)
+lvcreate -l 90%FREE lvmroot --name root
 
 # format as usual for root partition
 mkfs.ext4 -L "nixroot" /dev/mapper/lvmroot-root
@@ -47,7 +53,7 @@ mkswap -L "nixswap" /dev/mapper/lvmroot-swap
 # mount root
 mount /dev/disk/by-label/nixroot /mnt
 # mount boot
-mount --mkdir /dev/nvme0n1p1 /mnt/boot
+mount --mkdir /dev/disk/by-label/nixboot /mnt/boot
 # again, if you did the home volume
 mount --mkdir /dev/disk/by-label/nixhome /mnt/home
 # turn on swap
@@ -59,8 +65,7 @@ swapon /dev/disk/by-label/nixswap
 # generate templates and update the hardware-configuration.nix
 nixos-generate-config --root /mnt
 
-# add dm-crypt and dm-mod to the kernelModules
-boot.initrd.kernelModules = [ "dm-crypt" "dm-mod" ];
+# no extra kernelModules needed, luks and lvm load dm_crypt and dm_mod themselves
 
 # add file systems using labels
 fileSystems."/" =
@@ -81,7 +86,13 @@ swapDevices =
   ];
 
 # point the bootloader to the luks device
-boot.initrd.luks.devices."cryptroot".device = "/dev/disk/by-label/nixcrypt";
+boot.initrd.luks.devices."cryptroot" = {
+  device = "/dev/disk/by-label/nixcrypt";
+  # without this fstrim never reaches the ssd
+  allowDiscards = true;
+  # lower latency on nvme
+  bypassWorkqueues = true;
+};
 ```
 
 4. install nixos

README.md

@@ -6,20 +6,20 @@ My personal NixOS configurations.
 
 ```bash
 .
-├── flake.lock
-├── flake.nix # flake definition
+├── flake.nix # hosts and home-manager wiring
 ├── hosts
-│   └── neon
-│       ├── configuration.nix # import nix-modules for specific host
-│       └── hardware-configuration.nix # hardware configs for specific host
+│   ├── argon # desktop
+│   ├── neon # laptop
+│   └── default # test vm
+│       ├── configuration.nix # host-specific settings and module imports
+│       ├── hardware-configuration.nix # generated by nixos-generate-config
+│       └── niri.nix # host-specific niri settings (outputs, input)
 ├── modules
-│   ├── home-manager
-│   │   ├── xyz_module.nix
-│   └── nixos
-│       └── xyz_module.nix
+│   ├── home-manager # user modules, imported by users/aaron/home.nix
+│   └── nixos # system modules, imported by the hosts
 └── users
     └── aaron
-        └── home.nix # import home-manager modules for specific user
+        └── home.nix # imports home-manager modules
 ```
 
 ## installation

devenv.lock

@@ -0,0 +1,65 @@
+{
+  "nodes": {
+    "devenv": {
+      "locked": {
+        "dir": "src/modules",
+        "lastModified": 1790701375,
+        "narHash": "sha256-0FpLHIRDYiyo3EMTnMQSobZQknZaa3JuWo6vmMCK76o=",
+        "owner": "cachix",
+        "repo": "devenv",
+        "rev": "fe20b5cba7ab5e93ae73f956a8d3efc50e1753f4",
+        "type": "github"
+      },
+      "original": {
+        "dir": "src/modules",
+        "owner": "cachix",
+        "repo": "devenv",
+        "type": "github"
+      }
+    },
+    "nixpkgs": {
+      "inputs": {
+        "nixpkgs-src": "nixpkgs-src"
+      },
+      "locked": {
+        "lastModified": 1789506231,
+        "narHash": "sha256-vNkJbtmqyBfFhn/HnzQo4ROuoyYWuy/allqTfJb4kMY=",
+        "owner": "cachix",
+        "repo": "devenv-nixpkgs",
+        "rev": "c2f38fe7f9e04d9aadd354d380f2bd40531d9737",
+        "type": "github"
+      },
+      "original": {
+        "owner": "cachix",
+        "ref": "rolling",
+        "repo": "devenv-nixpkgs",
+        "type": "github"
+      }
+    },
+    "nixpkgs-src": {
+      "flake": false,
+      "locked": {
+        "lastModified": 1789370336,
+        "narHash": "sha256-6RSEDHIWQtesQKWSu5qRai8L2h4KgCgMEfJHstW99G4=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "c7def046b9a883d46974757852106483d741586f",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixpkgs-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "devenv": "devenv",
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

devenv.nix

@@ -0,0 +1,29 @@
+{ pkgs, ... }:
+
+{
+  packages = with pkgs; [
+    # gitea (git.0x29a.ch)
+    tea
+    # nix tooling
+    nixfmt # official formatter (RFC 166 style)
+    statix # lints for nix anti-patterns
+    deadnix # finds unused bindings and arguments
+    nixd # language server
+    nvd # diff system generations
+  ];
+
+  scripts = {
+    lint.exec = ''
+      set -e
+      statix check .
+      deadnix --fail --exclude hosts/*/hardware-configuration.nix -- .
+    '';
+    fmt.exec = ''
+      nixfmt $(git ls-files '*.nix')
+    '';
+  };
+
+  enterShell = ''
+    echo "nixconfig devenv: tea, lint, fmt"
+  '';
+}

devenv.yaml

@@ -0,0 +1,3 @@
+inputs:
+  nixpkgs:
+    url: github:cachix/devenv-nixpkgs/rolling

flake.lock

@@ -8,11 +8,11 @@
         ]
       },
       "locked": {
-        "lastModified": 1775087534,
-        "narHash": "sha256-91qqW8lhL7TLwgQWijoGBbiD4t7/q75KTi8NxjVmSmA=",
+        "lastModified": 1788450739,
+        "narHash": "sha256-glZLQlzIn1fXH6PazR2iUmTo7kzzyYSshrWhLS9TqCU=",
         "owner": "hercules-ci",
         "repo": "flake-parts",
-        "rev": "3107b77cd68437b9a76194f0f7f9c55f2329ca5b",
+        "rev": "31729ca8cbdb4fa927b34e5f4353e6a83f39e993",
         "type": "github"
       },
       "original": {
@@ -28,11 +28,11 @@
         ]
       },
       "locked": {
-        "lastModified": 1777004352,
-        "narHash": "sha256-SV+9PgNwZ8jHVCjK6YaCBzaheLSW7cDnm5DpOYrD8Vw=",
+        "lastModified": 1790819692,
+        "narHash": "sha256-rvubAPbh3QCliic3sAK+CXTrPCGgJstY52OTs/5H1J4=",
         "owner": "nix-community",
         "repo": "home-manager",
-        "rev": "6012cf1fed3eba66115f3fd117b9be6bd2a15b2f",
+        "rev": "c8ecc29e5175452bee4a2aa1ba2383856d795338",
         "type": "github"
       },
       "original": {
@@ -41,13 +41,33 @@
         "type": "github"
       }
     },
+    "nixos-hardware": {
+      "inputs": {
+        "nixpkgs": [
+          "nixpkgs"
+        ]
+      },
+      "locked": {
+        "lastModified": 1790948122,
+        "narHash": "sha256-fDMYyzY1lI5b8RuCMrvoaIgTeRwNnTG4dNk1ucROlQE=",
+        "owner": "NixOS",
+        "repo": "nixos-hardware",
+        "rev": "0953bb1a609df63013176e3463393f8df993d3ef",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "repo": "nixos-hardware",
+        "type": "github"
+      }
+    },
     "nixpkgs": {
       "locked": {
-        "lastModified": 1776548001,
-        "narHash": "sha256-ZSK0NL4a1BwVbbTBoSnWgbJy9HeZFXLYQizjb2DPF24=",
+        "lastModified": 1790689126,
+        "narHash": "sha256-ilerN1WLSvF+HMjziC/Wv99J5y02maDH+6hZPwsORKg=",
         "owner": "nixos",
         "repo": "nixpkgs",
-        "rev": "b12141ef619e0a9c1c84dc8c684040326f27cdcc",
+        "rev": "b4fd65b198c599cbe814fcb9f42d25d021595ec9",
         "type": "github"
       },
       "original": {
@@ -66,11 +86,11 @@
         "systems": "systems"
       },
       "locked": {
-        "lastModified": 1777051818,
-        "narHash": "sha256-2tuHuYmcg8HQSYamI1FoLLVFFOSYK2Alqr/cGiVIfG4=",
+        "lastModified": 1790541651,
+        "narHash": "sha256-/496IQz8qNWHHLnc3Zvr0l4uxJ34igNhJhn7ZKAefFk=",
         "owner": "nix-community",
         "repo": "nixvim",
-        "rev": "b684241888d9271ab5196383e24098ad4400a372",
+        "rev": "5980a626794486abad69fca7667f9c11dfbc3bd7",
         "type": "github"
       },
       "original": {
@@ -83,15 +103,14 @@
       "inputs": {
         "nixpkgs": [
           "nixpkgs"
-        ],
-        "noctalia-qs": "noctalia-qs"
+        ]
       },
       "locked": {
-        "lastModified": 1776888984,
-        "narHash": "sha256-Up2F/eoMuPUsZnPVYdH5TMHe1TBP2Ue1QuWd0vWZoxY=",
+        "lastModified": 1790718664,
+        "narHash": "sha256-LWil4xgSyqIFZ9sydvL1glFOoiqAOknWUwykC4sqxuY=",
         "owner": "noctalia-dev",
         "repo": "noctalia-shell",
-        "rev": "2c1808f9f8937fc0b82c54af513f7620fec56d71",
+        "rev": "fd9759c892fe5034b682c185695f1bee121cd5b3",
         "type": "github"
       },
       "original": {
@@ -100,88 +119,31 @@
         "type": "github"
       }
     },
-    "noctalia-qs": {
-      "inputs": {
-        "nixpkgs": [
-          "noctalia",
-          "nixpkgs"
-        ],
-        "systems": "systems_2",
-        "treefmt-nix": "treefmt-nix"
-      },
-      "locked": {
-        "lastModified": 1776585574,
-        "narHash": "sha256-j35EWhKoGhKrfcXcAOpoRVgXEPQt41Eukji/h59cnjk=",
-        "owner": "noctalia-dev",
-        "repo": "noctalia-qs",
-        "rev": "75d180c28a9ab4470e980f3d6f706ad6c5213add",
-        "type": "github"
-      },
-      "original": {
-        "owner": "noctalia-dev",
-        "repo": "noctalia-qs",
-        "type": "github"
-      }
-    },
     "root": {
       "inputs": {
         "home-manager": "home-manager",
+        "nixos-hardware": "nixos-hardware",
         "nixpkgs": "nixpkgs",
         "nixvim": "nixvim",
         "noctalia": "noctalia"
       }
     },
     "systems": {
+      "flake": false,
       "locked": {
-        "lastModified": 1681028828,
-        "narHash": "sha256-Vy1rq5AaRuLzOxct8nz4T6wlgyUR7zLU309k9mBC768=",
+        "lastModified": 1774449309,
+        "narHash": "sha256-brhZ8DmuGtzkCYHJg4HEd602amKm89Y9ytsFZ5uWD1w=",
         "owner": "nix-systems",
         "repo": "default",
-        "rev": "da67096a3b9bf56a91d16901293e51ba5b49a27e",
+        "rev": "c29398b59d2048c4ab79345812849c9bd15e9150",
         "type": "github"
       },
       "original": {
         "owner": "nix-systems",
+        "ref": "future-26.11",
         "repo": "default",
         "type": "github"
       }
-    },
-    "systems_2": {
-      "locked": {
-        "lastModified": 1689347949,
-        "narHash": "sha256-12tWmuL2zgBgZkdoB6qXZsgJEH9LR3oUgpaQq2RbI80=",
-        "owner": "nix-systems",
-        "repo": "default-linux",
-        "rev": "31732fcf5e8fea42e59c2488ad31a0e651500f68",
-        "type": "github"
-      },
-      "original": {
-        "owner": "nix-systems",
-        "repo": "default-linux",
-        "type": "github"
-      }
-    },
-    "treefmt-nix": {
-      "inputs": {
-        "nixpkgs": [
-          "noctalia",
-          "noctalia-qs",
-          "nixpkgs"
-        ]
-      },
-      "locked": {
-        "lastModified": 1775636079,
-        "narHash": "sha256-pc20NRoMdiar8oPQceQT47UUZMBTiMdUuWrYu2obUP0=",
-        "owner": "numtide",
-        "repo": "treefmt-nix",
-        "rev": "790751ff7fd3801feeaf96d7dc416a8d581265ba",
-        "type": "github"
-      },
-      "original": {
-        "owner": "numtide",
-        "repo": "treefmt-nix",
-        "type": "github"
-      }
     }
   },
   "root": "root",

flake.nix

@@ -11,35 +11,52 @@
       url = "github:noctalia-dev/noctalia-shell";
       inputs.nixpkgs.follows = "nixpkgs";
     };
+    nixos-hardware = {
+      url = "github:NixOS/nixos-hardware";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
     nixvim = {
       url = "github:nix-community/nixvim";
       inputs.nixpkgs.follows = "nixpkgs";
     };
   };
 
-  outputs = { self, nixpkgs, home-manager, nixvim, ... }@inputs:
-  let
-    mkHost = hostName: nixpkgs.lib.nixosSystem {
-      system = "x86_64-linux";
-      specialArgs = { inherit inputs; };
-      modules = [
-        ./hosts/${hostName}/hardware-configuration.nix
-        ./hosts/${hostName}/configuration.nix
-        home-manager.nixosModules.home-manager
-        {
-          home-manager.extraSpecialArgs = { inherit inputs; };
-          home-manager.users.aaron.imports = [
-            nixvim.homeModules.nixvim
-            ./users/aaron/home.nix
+  outputs =
+    {
+      nixpkgs,
+      home-manager,
+      nixvim,
+      ...
+    }@inputs:
+    let
+      mkHost =
+        hostName:
+        nixpkgs.lib.nixosSystem {
+          system = "x86_64-linux";
+          specialArgs = { inherit inputs; };
+          modules = [
+            ./hosts/${hostName}/hardware-configuration.nix
+            ./hosts/${hostName}/configuration.nix
+            home-manager.nixosModules.home-manager
+            {
+              home-manager.useGlobalPkgs = true;
+              home-manager.useUserPackages = true;
+              home-manager.backupCommand = "mv -f {file} {file}.hm-bak-$(date +%Y%m%d%H%M%S)";
+              home-manager.extraSpecialArgs = { inherit inputs; };
+              home-manager.users.aaron.imports = [
+                nixvim.homeModules.nixvim
+                ./users/aaron/home.nix
+              ];
+            }
           ];
-        }
-      ];
+        };
+    in
+    {
+      nixosConfigurations = {
+        default = mkHost "default";
+        neon = mkHost "neon";
+        argon = mkHost "argon";
+        krypton = mkHost "krypton";
+      };
     };
-  in {
-    nixosConfigurations = {
-      default = mkHost "default";
-      neon    = mkHost "neon";
-      argon   = mkHost "argon";
-    };
-  };
 }

hosts/argon/configuration.nix

@@ -1,15 +1,25 @@
-{ config, pkgs, inputs, ... }:
+# argon: desktop with an amd gpu and three luks-encrypted data drives.
+# The drives are unlocked in the initrd with keyfiles from /etc/nixos/keys.
 
+{ lib, pkgs, ... }:
+
+let
+  # luks name -> partition uuid, mounted at /mnt/<name>
+  drives = {
+    data1 = "dfae62cc-bad1-4879-bf9a-461bde833625";
+    data2 = "8312edae-9247-481b-a313-52a7f848f027";
+    nvmecache = "2352250e-4ebe-4f9a-bf66-0d4aaa961bd8";
+  };
+  key = name: "/etc/nixos/keys/${name}.key";
+in
 {
   imports = [
+    ../../modules/nixos/appimage.nix
+    ../../modules/nixos/astro.nix
     ../../modules/nixos/audio.nix
     ../../modules/nixos/bootloader.nix
-    ../../modules/nixos/calibre.nix
     ../../modules/nixos/certificates.nix
-    ../../modules/nixos/drives.nix
     ../../modules/nixos/gnupg.nix
-    ../../modules/nixos/gnuradio.nix
-    ../../modules/nixos/graphics.nix
     ../../modules/nixos/greetd.nix
     ../../modules/nixos/locales.nix
     ../../modules/nixos/networking.nix
@@ -21,13 +31,43 @@
     ../../modules/nixos/services.nix
     ../../modules/nixos/settings.nix
     ../../modules/nixos/steam.nix
+    ../../modules/nixos/thunar.nix
     ../../modules/nixos/users.nix
+    ../../modules/nixos/vial.nix
+  ];
+
+  # host-specific niri config (outputs, input devices)
+  home-manager.users.aaron.imports = [ ./niri.nix ];
+
+  # amd gpu: mesa/vulkan, and amdgpu in the initrd for plymouth
+  hardware.graphics = {
+    enable = true;
+    enable32Bit = true;
+  };
+  hardware.amdgpu.initrd.enable = true;
+
+  # encrypted data drives
+  boot.initrd.secrets = lib.mapAttrs' (name: _: lib.nameValuePair (key name) (key name)) drives;
+  boot.initrd.luks.devices = lib.mapAttrs (name: uuid: {
+    device = "/dev/disk/by-uuid/${uuid}";
+    keyFile = key name;
+    # trim for ssds, ignored by drives without discard support
+    allowDiscards = true;
+  }) drives;
+  fileSystems = lib.mapAttrs' (
+    name: _:
+    lib.nameValuePair "/mnt/${name}" {
+      device = "/dev/mapper/${name}";
+      fsType = "ext4";
+      options = [ "nofail" ];
+    }
+  ) drives;
+
+  environment.systemPackages = with pkgs; [
+    amdgpu_top
+    calibre # ebook management and kobo syncing
   ];
 
-  # set hostname
   networking.hostName = "argon";
-
-  # install state version
-  system.stateVersion = "25.11"; # Don't change
+  system.stateVersion = "25.11"; # don't change
 }
-

hosts/argon/hardware-configuration.nix

@@ -1,38 +1,57 @@
 # Do not modify this file!  It was generated by ‘nixos-generate-config’
 # and may be overwritten by future invocations.  Please make changes
 # to /etc/nixos/configuration.nix instead.
-{ config, lib, pkgs, modulesPath, ... }:
+{
+  config,
+  lib,
+  pkgs,
+  modulesPath,
+  ...
+}:
 
 {
-  imports =
-    [ (modulesPath + "/installer/scan/not-detected.nix")
-    ];
+  imports = [
+    (modulesPath + "/installer/scan/not-detected.nix")
+  ];
 
-  boot.initrd.availableKernelModules = [ "nvme" "xhci_pci" "ahci" "usbhid" "usb_storage" "sd_mod" ];
-  boot.initrd.kernelModules = [ "dm-crypt dm-mod" ];
-  boot.initrd.luks.devices."cryptroot".device = "/dev/disk/by-label/nixcrypt";
+  boot.initrd.availableKernelModules = [
+    "nvme"
+    "xhci_pci"
+    "ahci"
+    "usbhid"
+    "usb_storage"
+    "sd_mod"
+  ];
+  boot.initrd.luks.devices."cryptroot" = {
+    device = "/dev/disk/by-label/nixcrypt";
+    allowDiscards = true;
+    bypassWorkqueues = true;
+  };
   boot.kernelModules = [ ];
   boot.extraModulePackages = [ ];
 
-  fileSystems."/" =
-    { device = "/dev/mapper/lvmroot-root";
-      fsType = "ext4";
-    };
+  fileSystems."/" = {
+    device = "/dev/disk/by-label/nixroot";
+    fsType = "ext4";
+  };
 
-  fileSystems."/boot" =
-    { device = "/dev/disk/by-uuid/AC1C-20EB";
-      fsType = "vfat";
-      options = [ "fmask=0022" "dmask=0022" ];
-    };
-
-  fileSystems."/home" =
-    { device = "/dev/mapper/lvmroot-home";
-      fsType = "ext4";
-    };
-
-  swapDevices =
-    [ { device = "/dev/mapper/lvmroot-swap"; }
+  fileSystems."/boot" = {
+    device = "/dev/disk/by-label/nixboot";
+    fsType = "vfat";
+    options = [
+      "fmask=0022"
+      "dmask=0022"
     ];
+  };
+
+  fileSystems."/home" = {
+    device = "/dev/disk/by-label/nixhome";
+    fsType = "ext4";
+  };
+
+  swapDevices = [
+    { device = "/dev/disk/by-label/nixswap"; }
+  ];
 
   nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
   hardware.cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;

hosts/argon/niri.nix

@@ -0,0 +1,37 @@
+# argon: desktop with two 1440p monitors side by side
+
+{
+  wayland.windowManager.niri.settings = {
+    input = {
+      touchpad.off = { };
+      trackpoint.off = { };
+    };
+
+    _children = [
+      {
+        output = {
+          _args = [ "DP-1" ];
+          mode = "2560x1440@165.000";
+          scale = 1;
+          transform = "normal";
+          position._props = {
+            x = 0;
+            y = 0;
+          };
+        };
+      }
+      {
+        output = {
+          _args = [ "DP-2" ];
+          mode = "2560x1440@143.912";
+          scale = 1;
+          transform = "normal";
+          position._props = {
+            x = 2560;
+            y = 0;
+          };
+        };
+      }
+    ];
+  };
+}

hosts/default/configuration.nix

@@ -1,10 +1,13 @@
-# 0x29a nixos conifg
+# 0x29a nixos config
 
-{ pkgs, lib, ... }:
+{ pkgs, ... }:
 
 {
   # use flakes
-  nix.settings.experimental-features = [ "nix-command" "flakes" ];
+  nix.settings.experimental-features = [
+    "nix-command"
+    "flakes"
+  ];
 
   # configure bootloader
   boot.loader.systemd-boot.enable = false;
@@ -29,7 +32,7 @@
   services.qemuGuest.enable = true;
 
   # networking
-  networking.hostName = "nixos"; 
+  networking.hostName = "nixos";
   networking.networkmanager.enable = true;
 
   # time zone.
@@ -60,9 +63,10 @@
 
     windowManager.qtile = {
       enable = true;
-      extraPackages = python3Packages: with python3Packages; [
-        qtile-extras
-      ];
+      extraPackages =
+        python3Packages: with python3Packages; [
+          qtile-extras
+        ];
     };
   };
 
@@ -71,8 +75,8 @@
 
   # enable sound
   services.pipewire = {
-     enable = true;
-     pulse.enable = true;
+    enable = true;
+    pulse.enable = true;
   };
 
   # define a user account
@@ -97,7 +101,10 @@
     autosuggestions.enable = true;
     ohMyZsh = {
       enable = true;
-      plugins = [ "git" "sudo" ];
+      plugins = [
+        "git"
+        "sudo"
+      ];
       theme = "agnoster";
     };
   };
@@ -116,8 +123,8 @@
   # Some programs need SUID wrappers
   programs.mtr.enable = true;
   programs.gnupg.agent = {
-     enable = true;
-     enableSSHSupport = true;
+    enable = true;
+    enableSSHSupport = true;
   };
 
   # enable the OpenSSH daemon
@@ -130,4 +137,3 @@
   # install state version
   system.stateVersion = "25.05"; # Don't change
 }
-

hosts/default/hardware-configuration.nix

@@ -1,36 +1,56 @@
 # 0x29a nixos hardware configuration
 
-{ config, lib, pkgs, modulesPath, ... }:
+{
+  config,
+  lib,
+  pkgs,
+  modulesPath,
+  ...
+}:
 
 {
-  imports =
-    [ (modulesPath + "/profiles/qemu-guest.nix")
-    ];
+  imports = [
+    (modulesPath + "/profiles/qemu-guest.nix")
+  ];
 
   # boot and initrd configs
-  boot.initrd.availableKernelModules = [ "uhci_hcd" "ehci_pci" "ahci" "virtio_pci" "virtio_scsi" "sd_mod" "sr_mod" ];
-  boot.initrd.kernelModules = [ "dm-snapshot" "cryptd" ];
+  boot.initrd.availableKernelModules = [
+    "uhci_hcd"
+    "ehci_pci"
+    "ahci"
+    "virtio_pci"
+    "virtio_scsi"
+    "sd_mod"
+    "sr_mod"
+  ];
+  boot.initrd.kernelModules = [
+    "dm-snapshot"
+    "cryptd"
+  ];
   boot.kernelModules = [ ];
   boot.extraModulePackages = [ ];
   boot.initrd.luks.devices."cryptroot".device = "/dev/disk/by-label/nixcrypt";
 
   # file systems
-  fileSystems."/" =
-    { device = "/dev/disk/by-label/nixroot";
-      fsType = "ext4";
-    };
-  fileSystems."/boot" =
-    { device = "/dev/disk/by-label/nixboot";
-      fsType = "vfat";
-      options = [ "fmask=0022" "dmask=0022" ];
-    };
-  fileSystems."/home" =
-    { device = "/dev/disk/by-label/nixhome";
-      fsType = "ext4";
-    };
-  swapDevices =
-    [ { device = "/dev/disk/by-label/nixswap"; }
+  fileSystems."/" = {
+    device = "/dev/disk/by-label/nixroot";
+    fsType = "ext4";
+  };
+  fileSystems."/boot" = {
+    device = "/dev/disk/by-label/nixboot";
+    fsType = "vfat";
+    options = [
+      "fmask=0022"
+      "dmask=0022"
     ];
+  };
+  fileSystems."/home" = {
+    device = "/dev/disk/by-label/nixhome";
+    fsType = "ext4";
+  };
+  swapDevices = [
+    { device = "/dev/disk/by-label/nixswap"; }
+  ];
 
   # enable dhcp on all interfaces
   networking.useDHCP = lib.mkDefault true;

hosts/default/home.nix

@@ -1,4 +1,4 @@
-{ config, pkgs, ... }:
+{ pkgs, ... }:
 
 {
   # user config
@@ -29,7 +29,6 @@
     iotop
     iftop
     strace
-    ltrace
     lsof
     sysstat
     lm_sensors
@@ -51,12 +50,16 @@
     syntaxHighlighting.enable = true;
     oh-my-zsh = {
       enable = true;
-      plugins = [ "git" "sudo" "python" "ansible" ];
+      plugins = [
+        "git"
+        "sudo"
+        "python"
+        "ansible"
+      ];
       theme = "agnoster";
     };
   };
 
-
   ## deploy qtile config
   #home.file."qtile-config" = {
   #  target = ".config/qtile/config.py";

hosts/krypton/configuration.nix

@@ -0,0 +1,35 @@
+# krypton: framework 13 pro, intel core ultra x7 358H
+
+{ inputs, ... }:
+
+{
+  imports = [
+    inputs.nixos-hardware.nixosModules.framework-intel-core-ultra-series3
+    ../../modules/nixos/appimage.nix
+    ../../modules/nixos/astro.nix
+    ../../modules/nixos/audio.nix
+    ../../modules/nixos/bootloader.nix
+    ../../modules/nixos/certificates.nix
+    ../../modules/nixos/docker.nix
+    ../../modules/nixos/gnupg.nix
+    ../../modules/nixos/locales.nix
+    ../../modules/nixos/networking.nix
+    ../../modules/nixos/niri.nix
+    ../../modules/nixos/noctalia.nix
+    ../../modules/nixos/openssh.nix
+    ../../modules/nixos/packages.nix
+    ../../modules/nixos/protonvpn.nix
+    ../../modules/nixos/sddm.nix
+    ../../modules/nixos/services.nix
+    ../../modules/nixos/settings.nix
+    ../../modules/nixos/steam.nix
+    ../../modules/nixos/users.nix
+    ../../modules/nixos/vial.nix
+  ];
+
+  # host-specific niri config (input devices, laptop binds)
+  home-manager.users.aaron.imports = [ ./niri.nix ];
+
+  networking.hostName = "krypton";
+  system.stateVersion = "26.05"; # don't change
+}

hosts/krypton/hardware-configuration.nix

@@ -0,0 +1,60 @@
+# Do not modify this file!  It was generated by ‘nixos-generate-config’
+# and may be overwritten by future invocations.  Please make changes
+# to /etc/nixos/configuration.nix instead.
+{
+  config,
+  lib,
+  pkgs,
+  modulesPath,
+  ...
+}:
+
+{
+  imports = [
+    (modulesPath + "/installer/scan/not-detected.nix")
+  ];
+
+  boot.initrd.availableKernelModules = [
+    "xhci_pci"
+    "thunderbolt"
+    "nvme"
+    "usb_storage"
+    "sd_mod"
+  ];
+  boot.initrd.kernelModules = [ "dm-snapshot" ];
+  boot.initrd.luks.devices."cryptroot" = {
+    device = "/dev/disk/by-label/nixcrypt";
+    allowDiscards = true;
+    bypassWorkqueues = true;
+  };
+
+  boot.kernelModules = [ "kvm-intel" ];
+  boot.extraModulePackages = [ ];
+
+  fileSystems."/" = {
+    device = "/dev/disk/by-label/nixroot";
+    fsType = "ext4";
+  };
+
+  fileSystems."/boot" = {
+    device = "/dev/disk/by-label/nixboot";
+    fsType = "vfat";
+    options = [
+      "fmask=0022"
+      "dmask=0022"
+    ];
+  };
+
+  fileSystems."/home" = {
+    device = "/dev/disk/by-label/nixhome";
+    fsType = "ext4";
+  };
+
+  swapDevices = [
+    { device = "/dev/disk/by-label/nixswap"; }
+  ];
+
+  nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
+  hardware.cpu.intel.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+  hardware.cpu.intel.npu.enable = true;
+}

hosts/krypton/niri.nix

@@ -0,0 +1,24 @@
+# krypton: framework 13 laptop, the built-in display is auto-configured by niri
+
+{ lib, ... }:
+
+{
+  wayland.windowManager.niri.settings = {
+    input.touchpad = {
+      tap = { };
+      natural-scroll = { };
+    };
+
+    layout.gaps = lib.mkForce 10;
+
+    binds = {
+      "Print".screenshot = { };
+      "Ctrl+Print".screenshot-screen = { };
+      "Mod+Shift+P".power-off-monitors = { };
+
+      # finer brightness steps
+      "XF86MonBrightnessUp".spawn-sh = lib.mkForce "brightnessctl --class=backlight set +1%";
+      "XF86MonBrightnessDown".spawn-sh = lib.mkForce "brightnessctl --class=backlight set 1%-";
+    };
+  };
+}

hosts/neon/configuration.nix

@@ -1,7 +1,12 @@
-{ config, pkgs, inputs, ... }:
+# neon: thinkpad t14 gen1 (intel)
+
+{ inputs, ... }:
 
 {
   imports = [
+    inputs.nixos-hardware.nixosModules.lenovo-thinkpad-t14-intel-gen1
+    ../../modules/nixos/appimage.nix
+    ../../modules/nixos/astro.nix
     ../../modules/nixos/audio.nix
     ../../modules/nixos/bootloader.nix
     ../../modules/nixos/certificates.nix
@@ -13,17 +18,18 @@
     ../../modules/nixos/noctalia.nix
     ../../modules/nixos/openssh.nix
     ../../modules/nixos/packages.nix
+    ../../modules/nixos/protonvpn.nix
     ../../modules/nixos/sddm.nix
     ../../modules/nixos/services.nix
     ../../modules/nixos/settings.nix
     ../../modules/nixos/steam.nix
     ../../modules/nixos/users.nix
+    ../../modules/nixos/vial.nix
   ];
 
-  # set hostname
+  # host-specific niri config (input devices, laptop binds)
+  home-manager.users.aaron.imports = [ ./niri.nix ];
+
   networking.hostName = "neon";
-
-  # install state version
-  system.stateVersion = "25.11"; # Don't change
+  system.stateVersion = "25.11"; # don't change
 }
-

hosts/neon/hardware-configuration.nix

@@ -1,39 +1,61 @@
 # Do not modify this file!  It was generated by ‘nixos-generate-config’
 # and may be overwritten by future invocations.  Please make changes
 # to /etc/nixos/configuration.nix instead.
-{ config, lib, pkgs, modulesPath, ... }:
+{
+  config,
+  lib,
+  pkgs,
+  modulesPath,
+  ...
+}:
 
 {
-  imports =
-    [ (modulesPath + "/installer/scan/not-detected.nix")
-    ];
+  imports = [
+    (modulesPath + "/installer/scan/not-detected.nix")
+  ];
 
-  boot.initrd.availableKernelModules = [ "xhci_pci" "nvme" "usb_storage" "sd_mod" "rtsx_pci_sdmmc" ];
-  boot.initrd.kernelModules = [ "dm-snapshot" "cryptd" ];
-  boot.initrd.luks.devices."cryptroot".device = "/dev/disk/by-label/nixcrypt";
+  boot.initrd.availableKernelModules = [
+    "xhci_pci"
+    "nvme"
+    "usb_storage"
+    "sd_mod"
+    "rtsx_pci_sdmmc"
+  ];
+  boot.initrd.kernelModules = [
+    "dm-snapshot"
+    "cryptd"
+  ];
+  boot.initrd.luks.devices."cryptroot" = {
+    device = "/dev/disk/by-label/nixcrypt";
+    allowDiscards = true;
+    bypassWorkqueues = true;
+  };
 
   boot.kernelModules = [ "kvm-intel" ];
   boot.extraModulePackages = [ ];
 
-  fileSystems."/" =
-    { device = "/dev/disk/by-label/nixroot";
-      fsType = "ext4";
-    };
+  fileSystems."/" = {
+    device = "/dev/disk/by-label/nixroot";
+    fsType = "ext4";
+  };
 
-  fileSystems."/boot" =
-    { device = "/dev/disk/by-label/nixboot";
-      fsType = "vfat";
-      options = [ "fmask=0022" "dmask=0022" ];
-    };
-
-  fileSystems."/home" =
-    { device = "/dev/disk/by-label/nixhome";
-      fsType = "ext4";
-    };
-
-  swapDevices =
-    [ { device = "/dev/disk/by-label/nixswap"; }
+  fileSystems."/boot" = {
+    device = "/dev/disk/by-label/nixboot";
+    fsType = "vfat";
+    options = [
+      "fmask=0022"
+      "dmask=0022"
     ];
+  };
+
+  fileSystems."/home" = {
+    device = "/dev/disk/by-label/nixhome";
+    fsType = "ext4";
+  };
+
+  swapDevices = [
+    { device = "/dev/disk/by-label/nixswap"; }
+  ];
 
   networking.useDHCP = lib.mkDefault true;
   nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";

hosts/neon/niri.nix

@@ -0,0 +1,24 @@
+# neon: laptop, the built-in display is auto-configured by niri
+
+{ lib, ... }:
+
+{
+  wayland.windowManager.niri.settings = {
+    input.touchpad = {
+      tap = { };
+      natural-scroll = { };
+    };
+
+    layout.gaps = lib.mkForce 10;
+
+    binds = {
+      "Print".screenshot = { };
+      "Ctrl+Print".screenshot-screen = { };
+      "Mod+Shift+P".power-off-monitors = { };
+
+      # finer brightness steps
+      "XF86MonBrightnessUp".spawn-sh = lib.mkForce "brightnessctl --class=backlight set +1%";
+      "XF86MonBrightnessDown".spawn-sh = lib.mkForce "brightnessctl --class=backlight set 1%-";
+    };
+  };
+}

modules/home-manager/fonts.nix

@@ -1,4 +1,4 @@
-{ config, pkgs, inputs, ... }:
+{ pkgs, ... }:
 
 {
   # user fonts

modules/home-manager/ghostty.nix

@@ -1,5 +1,3 @@
-{ config, pkgs, inputs, ... }:
-
 {
   programs.ghostty = {
     enable = true;

modules/home-manager/git.nix

@@ -1,17 +1,41 @@
-{ config, pkgs, inputs, ... }:
+# Commits are signed with each machine's ~/.ssh/id_ed25519 through the ssh
+# agent. gitea verifies them against the account keys; allowed_signers gives
+# the local git the same trust, so `git log --show-signature` resolves too.
 
 {
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  email = "aaron@0x29a.ch";
+  signingKeys = [
+    "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIHRhwzo1oxaT3fEySSmILKNnu9v30cfjx5G7FKpmfqeX aaron@argon"
+    "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIGDkhvvTUcBSQdtXjX+Mw2Bp8HHhtiBm8aJi4ZxiBgZR aaron@neon"
+  ];
+in
+{
+  xdg.configFile."git/allowed_signers".text = lib.concatMapStrings (
+    key: "${email} ${key}\n"
+  ) signingKeys;
+
   programs.git = {
     enable = true;
     settings = {
-      push = { autoSetupRemote = true; };
+      push.autoSetupRemote = true;
       user = {
-        name  = "aaron";
-        email = "aaron@0x29a.ch";
+        name = "aaron";
+        inherit email;
       };
+      gpg.ssh.allowedSignersFile = "${config.xdg.configHome}/git/allowed_signers";
     };
     signing = {
-      key = "7A830180A05DAC59CDE43B0677D2F5DB48184456";
+      format = "ssh";
+      # the public key makes ssh-keygen sign through the agent
+      key = "${config.home.homeDirectory}/.ssh/id_ed25519.pub";
+      signer = "${pkgs.openssh}/bin/ssh-keygen";
       signByDefault = true;
     };
   };

modules/home-manager/niri.nix

@@ -0,0 +1,270 @@
+# Only renders ~/.config/niri/config.kdl; niri itself, its session and portals
+# come from modules/nixos/niri.nix. Outputs and input devices that differ
+# per machine live in hosts/<host>/niri.nix.
+
+{ lib, osConfig, ... }:
+
+let
+  # Mod+1..9 focus a workspace, Mod+Ctrl+1..9 move the column there
+  workspaceBinds = lib.mergeAttrsList (
+    map (n: {
+      "Mod+${toString n}".focus-workspace = n;
+      "Mod+Ctrl+${toString n}".move-column-to-workspace = n;
+    }) (lib.range 1 9)
+  );
+
+  # shell command that also works on the lock screen
+  lockedSh = cmd: {
+    _props.allow-when-locked = true;
+    spawn-sh = cmd;
+  };
+in
+{
+  wayland.windowManager.niri = {
+    # only on hosts that run niri
+    enable = osConfig.programs.niri.enable;
+
+    # validate the config against the installed niri
+    package = osConfig.programs.niri.package;
+    systemd.enable = false;
+    portalPackage = null;
+    xwaylandSatellitePackage = null; # installed system-wide
+
+    settings = {
+      input = {
+        keyboard = {
+          xkb.layout = "ch";
+          numlock = { };
+        };
+        mouse = {
+          natural-scroll = { };
+          accel-speed = 0.5;
+          scroll-method = "no-scroll";
+        };
+      };
+
+      environment.GTK_IM_MODULE = "simple";
+
+      layout = {
+        gaps = 16;
+        center-focused-column = "never";
+
+        preset-column-widths._children = [
+          { proportion = 0.33333; }
+          { proportion = 0.5; }
+          { proportion = 0.66667; }
+          { fixed = 2560; }
+        ];
+
+        default-column-width.proportion = 0.5;
+
+        focus-ring = {
+          on = { };
+          width = 2;
+          active-color = "#4c566a";
+          inactive-color = "#2e3440";
+          urgent-color = "#a3be8c";
+        };
+
+        border.off = { };
+
+        shadow = {
+          on = { };
+          draw-behind-window = true;
+          softness = 30;
+          spread = 10;
+          offset._props = {
+            x = 0;
+            y = 5;
+          };
+          color = "#0007";
+        };
+      };
+
+      spawn-at-startup = "noctalia";
+
+      hotkey-overlay.skip-at-startup = { };
+
+      screenshot-path = "~/Pictures/Screenshots/Screenshot from %Y-%m-%d %H-%M-%S.png";
+
+      _children = [
+        # Open the Firefox picture-in-picture player as floating by default.
+        {
+          window-rule._children = [
+            {
+              match._props = {
+                app-id = "firefox$";
+                title = "^Picture-in-Picture$";
+              };
+            }
+            { open-floating = true; }
+          ];
+        }
+        # Block out the password manager from screen capture.
+        {
+          window-rule._children = [
+            { match._props.app-id = "^org\\.keepassxc\\.KeePassXC$"; }
+            { block-out-from = "screen-capture"; }
+          ];
+        }
+        {
+          window-rule = {
+            geometry-corner-radius = 12;
+            clip-to-geometry = true;
+          };
+        }
+      ];
+
+      binds = workspaceBinds // {
+        # programs: terminal, app launcher, screen locker
+        "Mod+Return" = {
+          _props.hotkey-overlay-title = "Open a Terminal";
+          spawn = "ghostty";
+        };
+        "Mod+D" = {
+          _props.hotkey-overlay-title = "Run an Application";
+          spawn-sh = "noctalia msg panel-toggle launcher";
+        };
+        "Super+Alt+L" = {
+          _props.hotkey-overlay-title = "Lock the Screen";
+          spawn-sh = "noctalia msg session lock";
+        };
+
+        # media keys (PipeWire / WirePlumber)
+        "XF86AudioRaiseVolume" = lockedSh "wpctl set-volume @DEFAULT_SINK@ 0.01+ -l 1.0";
+        "XF86AudioLowerVolume" = lockedSh "wpctl set-volume @DEFAULT_SINK@ 0.01-";
+        "XF86AudioMute" = lockedSh "wpctl set-mute @DEFAULT_SINK@ toggle";
+        "XF86AudioMicMute" = lockedSh "wpctl set-mute @DEFAULT_SOURCE@ toggle";
+        "XF86AudioPlay" = lockedSh "playerctl play-pause";
+        "XF86AudioStop" = lockedSh "playerctl stop";
+        "XF86AudioPrev" = lockedSh "playerctl previous";
+        "XF86AudioNext" = lockedSh "playerctl next";
+        "XF86MonBrightnessUp" = lockedSh "brightnessctl --class=backlight set +10%";
+        "XF86MonBrightnessDown" = lockedSh "brightnessctl --class=backlight set 10%-";
+
+        "Mod+O" = {
+          _props.repeat = false;
+          toggle-overview = { };
+        };
+        "Mod+Q" = {
+          _props.repeat = false;
+          close-window = { };
+        };
+
+        # focus / move columns and windows
+        "Mod+Left".focus-column-left = { };
+        "Mod+Down".focus-window-down = { };
+        "Mod+Up".focus-window-up = { };
+        "Mod+Right".focus-column-right = { };
+        "Mod+H".focus-column-left = { };
+        "Mod+J".focus-window-down = { };
+        "Mod+K".focus-window-up = { };
+        "Mod+L".focus-column-right = { };
+
+        "Mod+Shift+Left".move-column-left = { };
+        "Mod+Shift+Down".move-window-down = { };
+        "Mod+Shift+Up".move-window-up = { };
+        "Mod+Shift+Right".move-column-right = { };
+        "Mod+Shift+H".move-column-left = { };
+        "Mod+Shift+J".move-window-down = { };
+        "Mod+Shift+K".move-window-up = { };
+        "Mod+Shift+L".move-column-right = { };
+
+        "Mod+Home".focus-column-first = { };
+        "Mod+End".focus-column-last = { };
+        "Mod+Ctrl+Home".move-column-to-first = { };
+        "Mod+Ctrl+End".move-column-to-last = { };
+
+        # move columns between monitors
+        "Mod+Ctrl+Left".move-column-to-monitor-left = { };
+        "Mod+Ctrl+Down".move-column-to-monitor-down = { };
+        "Mod+Ctrl+Up".move-column-to-monitor-up = { };
+        "Mod+Ctrl+Right".move-column-to-monitor-right = { };
+        "Mod+Ctrl+H".move-column-to-monitor-left = { };
+        "Mod+Ctrl+J".move-column-to-monitor-down = { };
+        "Mod+Ctrl+K".move-column-to-monitor-up = { };
+        "Mod+Ctrl+L".move-column-to-monitor-right = { };
+
+        # workspaces
+        "Mod+Page_Down".focus-workspace-down = { };
+        "Mod+Page_Up".focus-workspace-up = { };
+        "Mod+U".focus-workspace-down = { };
+        "Mod+I".focus-workspace-up = { };
+        "Mod+Ctrl+Page_Down".move-column-to-workspace-down = { };
+        "Mod+Ctrl+Page_Up".move-column-to-workspace-up = { };
+        "Mod+Ctrl+U".move-column-to-workspace-down = { };
+        "Mod+Ctrl+I".move-column-to-workspace-up = { };
+
+        "Mod+Shift+Page_Down".move-workspace-down = { };
+        "Mod+Shift+Page_Up".move-workspace-up = { };
+        "Mod+Shift+U".move-workspace-down = { };
+        "Mod+Shift+I".move-workspace-up = { };
+
+        # mouse wheel
+        "Mod+WheelScrollDown" = {
+          _props.cooldown-ms = 150;
+          focus-workspace-down = { };
+        };
+        "Mod+WheelScrollUp" = {
+          _props.cooldown-ms = 150;
+          focus-workspace-up = { };
+        };
+        "Mod+Ctrl+WheelScrollDown" = {
+          _props.cooldown-ms = 150;
+          move-column-to-workspace-down = { };
+        };
+        "Mod+Ctrl+WheelScrollUp" = {
+          _props.cooldown-ms = 150;
+          move-column-to-workspace-up = { };
+        };
+
+        "Mod+WheelScrollRight".focus-column-right = { };
+        "Mod+WheelScrollLeft".focus-column-left = { };
+        "Mod+Ctrl+WheelScrollRight".move-column-right = { };
+        "Mod+Ctrl+WheelScrollLeft".move-column-left = { };
+
+        "Mod+Shift+WheelScrollDown".focus-column-right = { };
+        "Mod+Shift+WheelScrollUp".focus-column-left = { };
+        "Mod+Ctrl+Shift+WheelScrollDown".move-column-right = { };
+        "Mod+Ctrl+Shift+WheelScrollUp".move-column-left = { };
+
+        # columns
+        "Mod+BracketLeft".consume-or-expel-window-left = { };
+        "Mod+BracketRight".consume-or-expel-window-right = { };
+        "Mod+Comma".consume-window-into-column = { };
+        "Mod+Period".expel-window-from-column = { };
+
+        "Mod+R".switch-preset-column-width = { };
+        "Mod+Shift+R".switch-preset-window-height = { };
+        "Mod+Ctrl+R".reset-window-height = { };
+        "Mod+F".maximize-column = { };
+        "Mod+Shift+F".fullscreen-window = { };
+        "Mod+Ctrl+F".expand-column-to-available-width = { };
+
+        "Mod+C".center-column = { };
+        "Mod+Ctrl+C".center-visible-columns = { };
+
+        "Mod+Minus".set-column-width = "-10%";
+        "Mod+Equal".set-column-width = "+10%";
+        "Mod+Shift+Minus".set-window-height = "-10%";
+        "Mod+Shift+Equal".set-window-height = "+10%";
+
+        "Mod+Space".toggle-window-floating = { };
+        "Mod+Shift+Space".switch-focus-between-floating-and-tiling = { };
+        "Mod+W".toggle-column-tabbed-display = { };
+
+        # screenshots
+        "Mod+P".screenshot = { };
+        "Alt+Print".screenshot-window = { };
+
+        # escape hatch for apps that inhibit keyboard shortcuts
+        "Mod+Escape" = {
+          _props.allow-inhibiting = false;
+          toggle-keyboard-shortcuts-inhibit = { };
+        };
+
+        "Mod+Shift+E".quit = { };
+      };
+    };
+  };
+}

modules/home-manager/nixvim.nix

@@ -1,12 +1,17 @@
-{ config, pkgs, inputs, ... }:
+{ pkgs, inputs, ... }:
 
 {
   programs.nixvim = {
     enable = true;
 
-    viAlias = false;
+    # same nixpkgs as the flake's `follows`, silences nixvim's pin warning
+    nixpkgs.source = inputs.nixpkgs;
+
+    # set aliases
+    viAlias = true;
     vimAlias = true;
 
+    # default vim options
     opts = {
       number = true;
       relativenumber = true;
@@ -16,24 +21,78 @@
       incsearch = true;
     };
 
-    colorschemes.nord.enable = true;
+    # nvim mapleader for all command below
     globals.mapleader = " ";
+    # set colorscheme to nord
+    colorschemes.nord.enable = true;
 
+    # nvim plugins
+    plugins.indent-blankline.enable = true;
     plugins.lualine.enable = true;
     plugins.nix.enable = true;
     plugins.nvim-tree.enable = true;
+    plugins.web-devicons.enable = true;
+    plugins.telescope = {
+      enable = true;
+      keymaps = {
+        "<leader>ff" = "find_files";
+        "<leader>fg" = "live_grep";
+        "<leader>fb" = "buffers";
+        "<leader>fh" = "help_tags";
+      };
+    };
+    plugins.lsp = {
+      enable = true;
+      servers.tinymist = {
+        enable = true;
+        settings = {
+          formatterMode = "typstyle";
+          exportPdf = "onSave";
+          semanticTokens = "disable"; # treesitter handles highlighting better
+        };
+      };
+      servers.pyright.enable = true;
+      servers.ruff.enable = true;
+      keymaps.lspBuf = {
+        "<leader>K" = "hover";
+        "<leader>gd" = "definition";
+        "<leader>gr" = "references";
+        "<leader>f" = "format";
+        "<leader>rn" = "rename";
+        "<leader>ca" = "code_action";
+      };
+    };
     plugins.treesitter = {
       enable = true;
-      settings.ensure_installed = [ "markdown" "markdown_inline" ];
+      settings.ensure_installed = [
+        "markdown"
+        "markdown_inline"
+        "typst"
+      ];
+    };
+    plugins.typst-preview = {
+      enable = true;
+      settings = {
+        open_cmd = "firefox %s";
+        dependencies_bin = {
+          tinymist = "tinymist";
+          websocat = null;
+        };
+      };
+    };
+    plugins.typst-vim = {
+      enable = true;
+      settings.pdf_viewer = "zathura";
     };
-    plugins.telescope.enable = true;
-    plugins.web-devicons.enable = true;
-    plugins.indent-blankline.enable = true;
     plugins.render-markdown = {
       enable = true;
       settings = {
         # render in normal mode, raw source in insert
-        render_modes = [ "n" "c" "t"];
+        render_modes = [
+          "n"
+          "c"
+          "t"
+        ];
         pipe_table.preset = "round";
         heading.width = "block";
         file_types = [ "markdown" ];
@@ -41,4 +100,7 @@
       };
     };
   };
+
+  # telescope live_grep
+  home.packages = [ pkgs.ripgrep ];
 }

modules/home-manager/noctalia.nix

@@ -0,0 +1,148 @@
+{ pkgs, inputs, ... }:
+
+{
+  # Noctalia v5 shell, managed via home-manager's built-in programs.noctalia module.
+  # The noctalia flake's homeModules.default is not imported: it redeclares the same
+  # options and its disabledModules path ("programs/noctalia.nix") doesn't match HM's.
+  # See https://docs.noctalia.dev/v5/getting-started/nixos/
+
+  programs.noctalia = {
+    enable = true;
+
+    # Use the package from the noctalia flake rather than nixpkgs.
+    package = inputs.noctalia.packages.${pkgs.stdenv.hostPlatform.system}.default;
+
+    # settings is rendered to ~/.config/noctalia/config.toml
+    settings = {
+      # theme / colors
+      theme = {
+        source = "builtin";
+        builtin = "Nord";
+        mode = "dark";
+        templates.builtin_ids = [ "ghostty" ];
+      };
+
+      # general
+      shell = {
+        font_family = "0xProto Nerd Font";
+        avatar_path = "/home/aaron/syncthing/pictures/Logo-Aaron-Totenkopf-rund-schwarz.png";
+        telemetry_enabled = false;
+        clipboard_enabled = true;
+        password_style = "random";
+
+        launcher = {
+          categories = false;
+          providers.emoji.global = false;
+        };
+
+        panel = {
+          open_near_click_control_center = true;
+          open_near_click_session = true;
+          open_near_click_wallpaper = true;
+          transparency_mode = "glass";
+        };
+
+        screen_corners = {
+          enabled = true;
+          size = 10;
+        };
+      };
+
+      # location / weather
+      location.address = "Bern";
+
+      weather = {
+        enabled = true;
+        unit = "metric";
+      };
+
+      # wallpaper
+      wallpaper = {
+        enabled = true;
+        directory = "/home/aaron/Pictures/Wallpapers";
+        fill_mode = "crop";
+        default.path = "/home/aaron/Pictures/Wallpapers/nord-theme-tower.png";
+      };
+
+      # bar layout
+      bar = {
+        order = [ "default" ];
+        default = {
+          position = "top";
+          background_opacity = 0.93;
+          font_weight = 400;
+          margin_edge = 0;
+          margin_ends = 0;
+          radius = 0;
+          scale = 1.2;
+          widget_spacing = 20;
+          start = [
+            "control-center"
+            "cpu"
+            "ram"
+            "temp"
+            "active_window"
+          ];
+          center = [ "workspaces" ];
+          end = [
+            "tray"
+            "bluetooth"
+            "notifications"
+            "volume"
+            "network"
+            "clock"
+          ];
+        };
+      };
+
+      # per-widget styling
+      widget = {
+        bluetooth.capsule = true;
+        control-center = {
+          capsule_radius = 8;
+          custom_image = "/home/aaron/syncthing/pictures/nix_flake_logo.png";
+          scale = 1.4;
+        };
+        cpu.capsule = true;
+        network = {
+          capsule = true;
+          show_label = false;
+        };
+        notifications.capsule = true;
+        ram.capsule = true;
+        temp.capsule = true;
+        volume = {
+          capsule = true;
+          show_label = false;
+        };
+      };
+
+      # idle behavior
+      idle = {
+        pre_action_fade_seconds = 5;
+        behavior_order = [
+          "screen-off"
+          "lock"
+          "lock-and-suspend"
+        ];
+        behavior = {
+          "screen-off" = {
+            action = "screen_off";
+            enabled = true;
+            timeout = 300;
+          };
+          "lock" = {
+            action = "lock";
+            enabled = true;
+            timeout = 600;
+          };
+          "lock-and-suspend" = {
+            action = "lock_and_suspend";
+            enabled = true;
+            timeout = 1800;
+          };
+        };
+      };
+    };
+  };
+}

modules/home-manager/programs.nix

@@ -1,4 +1,4 @@
-{ config, pkgs, inputs, ... }:
+{ config, pkgs, ... }:
 
 {
   # user packages
@@ -8,6 +8,8 @@
     fastfetch
     keepassxc
     teamspeak6-client
+    typst
+    zathura
   ];
 
   # services and other software
@@ -16,5 +18,8 @@
 
   # browsers
   programs.chromium.enable = true;
-  programs.firefox.enable = true;
+  programs.firefox = {
+    enable = true;
+    configPath = "${config.xdg.configHome}/mozilla/firefox";
+  };
 }

modules/home-manager/shell.nix

@@ -1,28 +1,48 @@
-{ config, lib, pkgs, inputs, ... }:
- 
+# zsh with oh-my-zsh: agnoster where glyphs render, gentoo on the console.
+# Deep paths are shortened to `…/last/two` so the prompt stays on one line:
+# `%(4~|…/%2~|%~)` shows the last two components from four levels down.
+
+{ lib, ... }:
+
 {
-  # configure z-shell to use omz with some plugins
   programs.zsh = {
     enable = true;
     autosuggestion.enable = true;
     syntaxHighlighting.enable = true;
     oh-my-zsh = {
       enable = true;
-      # theme will be set below
-      theme = "";
-      plugins = [ "git" "ssh-agent" "gpg-agent" ];
+      plugins = [
+        "git"
+        "ssh-agent"
+        "gpg-agent"
+      ];
+      # runs before oh-my-zsh is sourced
+      extraConfig = ''
+        # faster git status on large repositories
+        DISABLE_UNTRACKED_FILES_DIRTY=true
+
+        if [[ "$TERM" == "linux" || "$TERM" == "screen" ]]; then
+          ZSH_THEME="gentoo"
+        else
+          ZSH_THEME="agnoster"
+        fi
+      '';
     };
-    # only display a fancy theme when glyphs are rendered
-    initContent = lib.mkOrder 550 ''
-      if [[ "$TERM" == "linux" || "$TERM" == "screen" ]]; then
-        ZSH_THEME="gentoo"
+
+    # runs after oh-my-zsh, once the theme's prompt exists
+    initContent = lib.mkAfter ''
+      if [[ "$ZSH_THEME" == "agnoster" ]]; then
+        # agnoster renders prompt_dir on every prompt, so override it
+        prompt_dir() {
+          prompt_segment "$AGNOSTER_DIR_BG" "$AGNOSTER_DIR_FG" '%(4~|…/%2~|%~)'
+        }
       else
-        ZSH_THEME="agnoster"
+        # gentoo builds PROMPT once; ascii dots, the console font lacks …
+        PROMPT="''${PROMPT/\%~/%(4~|.../%2~|%~)}"
       fi
     '';
   };
 
-  # set important env vars
   home.sessionVariables = {
     EDITOR = "vim";
     NH_FLAKE = "/home/aaron/git/nixconfig";

modules/home-manager/styling.nix

@@ -1,19 +1,17 @@
-{ config, pkgs, inputs, ... }:
+{ pkgs, ... }:
 
 {
-  # set gtk theme
   gtk = {
     enable = true;
     theme = {
       name = "Adwaita-dark";
-        package = pkgs.gnome-themes-extra;
-      };
+      package = pkgs.gnome-themes-extra;
+    };
     gtk3.extraConfig.gtk-application-prefer-dark-theme = 1;
     gtk4.theme = null;
     gtk4.extraConfig.gtk-application-prefer-dark-theme = 1;
   };
 
-  # set qt theme
   qt = {
     enable = true;
     platformTheme.name = "qt6";
@@ -22,10 +20,4 @@
       package = pkgs.adwaita-qt;
     };
   };
-
-  # ensure packages are installed
-  home.packages = with pkgs; [
-    gnome-themes-extra
-    adwaita-qt
-  ];
 }

modules/home-manager/tmux.nix

@@ -1,60 +1,95 @@
-{ config, pkgs, inputs, ... }:
+# Nord-style status line built natively, no theme plugin.
+# The powerline separators (U+E0B0..U+E0B3) are written as escapes via
+# fromJSON: literal private-use glyphs get stripped silently on copy/paste.
+# Commas inside #{?...} separate arguments, hence the escaped `#,` below.
 
+let
+  sep = builtins.fromJSON ''
+    {
+      "right":     "",
+      "rightThin": "",
+      "left":      "",
+      "leftThin":  ""
+    }
+  '';
+in
 {
   programs.tmux = {
     enable = true;
     prefix = "C-a";
     keyMode = "vi";
     mouse = true;
-    terminal = "screen-256color";
+    terminal = "tmux-256color"; # truecolor, italics and undercurl in nvim
+    escapeTime = 10; # the 500ms default lags leaving insert mode in nvim
+    focusEvents = true; # nvim autoread
+    historyLimit = 50000;
+    baseIndex = 1; # window numbers match the number row
+
     extraConfig = ''
-      # Status keys
       set -g status-keys vi
+
+      # outer terminal does 24-bit colour
+      set -sa terminal-features ",*:RGB"
+
+      # forward Shift+Enter and other extended keys as CSI-u (tmux >= 3.5)
+      set -s extended-keys always
+      set -s extended-keys-format csi-u
+      set -as terminal-features '*:extkeys'
+
       # Status bar options
-      set -g status-interval 1
-      set -g status on
+      set -g status-interval 5
       set -g status-justify left
+
       # Clock mode
       setw -g clock-mode-colour cyan
+
       # Colors
       set -g status-bg black
       set -g status-fg white
+
       # Key bindings
-      # Reload configuration 
-      bind r source-file ~/.config/tmux/tmux.conf
-      # Panel split and selection
+      bind r source-file ~/.config/tmux/tmux.conf \; display-message "tmux.conf reloaded"
+
+      # Panel split and selection, new panes/windows inherit the cwd
       unbind %
       unbind '"'
-      bind v split-window -v
-      bind c split-window -h
-      bind i new-window
-      bind b previous-window
-      bind n next-window
+      bind v split-window -v -c "#{pane_current_path}"
+      bind c split-window -h -c "#{pane_current_path}"
+      bind i new-window -c "#{pane_current_path}"
+      bind -r b previous-window
+      bind -r n next-window
+
       # Move around panes with hjkl
       bind h select-pane -L
       bind j select-pane -D
       bind k select-pane -U
       bind l select-pane -R
+
       # Resize panes
-      bind H resize-pane -L 5
-      bind J resize-pane -D 5
-      bind K resize-pane -U 5
-      bind L resize-pane -R 5
-      # Wayland clipboard integration
-      # Copy selection to both clipboard (Ctrl+V / Shift+Insert) and primary (middle-click)
+      bind -r H resize-pane -L 5
+      bind -r J resize-pane -D 5
+      bind -r K resize-pane -U 5
+      bind -r L resize-pane -R 5
+
+      # copy to both the clipboard and primary selection
+      bind -T copy-mode-vi v send-keys -X begin-selection
+      bind -T copy-mode-vi C-v send-keys -X rectangle-toggle
       bind -T copy-mode-vi y send-keys -X copy-pipe-and-cancel "wl-copy && wl-copy --primary"
       bind -T copy-mode-vi Enter send-keys -X copy-pipe-and-cancel "wl-copy && wl-copy --primary"
       bind -T copy-mode-vi MouseDragEnd1Pane send-keys -X copy-pipe-and-cancel "wl-copy && wl-copy --primary"
+
       # Kill commands
-      bind q kill-window
-      bind Q kill-session
+      bind q confirm-before -p "kill window #W? (y/n)" kill-window
+      bind Q confirm-before -p "kill session #S? (y/n)" kill-session
+
       # Bars
       set -g status-left-length 24
-      set -g status-left "#[fg=black,bg=blue,bold] #{=20:session_name} #[fg=blue,bg=black,nobold,noitalics,nounderscore]"
-      set -g status-right "#{prefix_highlight}#[fg=brightblack,bg=black,nobold,noitalics,nounderscore]#[fg=white,bg=brightblack] %Y-%m-%d #[fg=white,bg=brightblack,nobold,noitalics,nounderscore]#[fg=white,bg=brightblack] %H:%M #[fg=cyan,bg=brightblack,nobold,noitalics,nounderscore]#[fg=black,bg=cyan,bold] #H "
+      set -g status-left "#[fg=black,bg=blue,bold] #{=20:session_name} #[fg=blue,bg=black,nobold,noitalics,nounderscore]${sep.right}"
+      set -g status-right "#{?client_prefix,#[fg=black#,bg=yellow#,bold] ^A ,}#[fg=brightblack,bg=black,nobold,noitalics,nounderscore]${sep.left}#[fg=white,bg=brightblack] %Y-%m-%d #[fg=white,bg=brightblack,nobold,noitalics,nounderscore]${sep.leftThin}#[fg=white,bg=brightblack] %H:%M #[fg=cyan,bg=brightblack,nobold,noitalics,nounderscore]${sep.left}#[fg=black,bg=cyan,bold] #H "
+
       # Windows
-      set -g window-status-format "#[fg=black,bg=brightblack,nobold,noitalics,nounderscore] #[fg=white,bg=brightblack]#I #[fg=white,bg=brightblack,nobold,noitalics,nounderscore] #[fg=white,bg=brightblack]#W #F #[fg=brightblack,bg=black,nobold,noitalics,nounderscore]"
-      set -g window-status-current-format "#[fg=black,bg=cyan,nobold,noitalics,nounderscore] #[fg=black,bg=cyan]#I #[fg=black,bg=cyan,nobold,noitalics,nounderscore] #[fg=black,bg=cyan]#W #F #[fg=cyan,bg=black,nobold,noitalics,nounderscore]"
+      set -g window-status-format "#[fg=black,bg=brightblack,nobold,noitalics,nounderscore]${sep.right} #[fg=white,bg=brightblack]#I #[fg=white,bg=brightblack,nobold,noitalics,nounderscore]${sep.rightThin} #[fg=white,bg=brightblack]#W #F #[fg=brightblack,bg=black,nobold,noitalics,nounderscore]${sep.right}"
+      set -g window-status-current-format "#[fg=black,bg=cyan,nobold,noitalics,nounderscore]${sep.right} #[fg=black,bg=cyan]#I #[fg=black,bg=cyan,nobold,noitalics,nounderscore]${sep.rightThin} #[fg=black,bg=cyan]#W #F #[fg=cyan,bg=black,nobold,noitalics,nounderscore]${sep.right}"
       set -g window-status-separator ""
     '';
   };

modules/nixos/appimage.nix

@@ -0,0 +1,10 @@
+# Running an AppImage directly fails on NixOS: its runtime dlopens
+# libfuse.so.2, which nix-ld doesn't cover. appimage-run unpacks the image
+# into an FHS sandbox instead. Used for the BitBox02 wallet from bitbox.swiss.
+
+{
+  programs.appimage = {
+    enable = true;
+    binfmt = true; # ./Something.AppImage runs without the appimage-run prefix
+  };
+}

modules/nixos/astro.nix

@@ -0,0 +1,72 @@
+# Stellarium for target finding, Siril for stacking.
+#
+# Siril's python plugins run in a venv of foreign manylinux wheels (numpy,
+# PyQt6, ...), dlopened by nixpkgs python, so nix-ld doesn't help. The wrapper
+# puts their libs on LD_LIBRARY_PATH, a python on PATH to bootstrap the venv,
+# and adwaita-qt6 on QT_PLUGIN_PATH so the dark style override resolves.
+# The python comes from /etc/siril/bin, a stable symlink: a /nix/store path
+# would leave the venv dangling after the next python bump and gc.
+#
+# StarNet++ has no package: unzip the v2 ORT cli build from starnetastro.com
+# to ~/.local/share/siril/starnet/ and point Siril's preferences at ./starnet2.
+# It runs through nix-ld and finds its own libs in the bundled ./lib.
+
+{ lib, pkgs, ... }:
+
+let
+  sirilWithPlugins = pkgs.symlinkJoin {
+    name = "siril-with-plugins";
+    paths = [ pkgs.siril ];
+    nativeBuildInputs = [ pkgs.makeWrapper ];
+    postBuild = ''
+      wrapProgram $out/bin/siril \
+        --prefix PATH : /etc/siril/bin \
+        --prefix QT_PLUGIN_PATH : ${pkgs.adwaita-qt6}/lib/qt-6/plugins \
+        --prefix LD_LIBRARY_PATH : ${
+          lib.makeLibraryPath (
+            with pkgs;
+            [
+              stdenv.cc.cc.lib # libstdc++, libgcc_s, libgomp (numpy)
+              zlib
+              zstd # PyQt6
+              libGL # PyQt6
+              # Qt needs these even on wayland
+              glib
+              fontconfig
+              freetype
+              dbus
+              libxkbcommon
+              # Qt platform plugins: wayland, and the xcb fallback
+              wayland
+              libxcb-cursor
+              libx11
+              libxcb
+              libxcb-util
+              libxcb-wm
+              libxcb-image
+              libxcb-keysyms
+              libxcb-render-util
+            ]
+          )
+        }
+    '';
+  };
+in
+{
+  environment.systemPackages = [
+    pkgs.stellarium
+    sirilWithPlugins
+  ];
+
+  # same python siril propagates, so sirilpy's abi matches
+  environment.etc."siril/bin/python3".source = "${pkgs.python3}/bin/python3";
+
+  # for StarNet++
+  programs.nix-ld = {
+    enable = true;
+    libraries = with pkgs; [
+      stdenv.cc.cc.lib
+      zlib
+    ];
+  };
+}

modules/nixos/audio.nix

@@ -1,9 +1,7 @@
-{ config, lib, pkgs, ... }:
-
 {
   # enable sound through pipewire
   services.pipewire = {
-     enable = true;
-     pulse.enable = true;
+    enable = true;
+    pulse.enable = true;
   };
 }

modules/nixos/bootloader.nix

@@ -1,4 +1,4 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
   # set bootloader to systemd
@@ -9,7 +9,7 @@
 
   # enable systemd initrd
   boot.initrd.systemd.enable = true;
-  
+
   # plymouth
   boot.plymouth = {
     enable = true;
@@ -17,10 +17,19 @@
   };
 
   # kernel options
-  boot.kernelParams = [ "quiet" "acpi.debug_level=0"];
+  boot.kernelParams = [
+    "quiet"
+    "acpi.debug_level=0"
+  ];
   boot.kernelPackages = pkgs.linuxPackages_latest;
   boot.consoleLogLevel = 2;
 
+  # /tmp in RAM, nix builds go to /var/tmp instead (see settings.nix)
+  boot.tmp = {
+    useTmpfs = true;
+    tmpfsSize = "50%";
+  };
+
   # Add boot-related packages
   environment.systemPackages = with pkgs; [
     efibootmgr

modules/nixos/calibre.nix

@@ -1,8 +0,0 @@
-{ config, lib, pkgs, ... }:
-
-{
-  # install calibre for ebook management and kobo syncing
-  environment.systemPackages = with pkgs; [
-    calibre
-  ];
-}

modules/nixos/certificates.nix

@@ -1,5 +1,3 @@
-{ config, lib, pkgs, ... }:
-
 let
   caddyRootCA = ''
     -----BEGIN CERTIFICATE-----

modules/nixos/docker.nix

@@ -1,26 +1,15 @@
-{ config, lib, pkgs, ...}:
-
 {
-  # add docker group to user
-  users.users.aaron.extraGroups = [ "docker" ];
-
-  virtualisation.docker = {
+  # rootless only: no root daemon and no root-equivalent docker group
+  virtualisation.docker.rootless = {
     enable = true;
-    # Customize Docker daemon settings
+    setSocketVariable = true;
     daemon.settings = {
-      dns = [ "1.1.1.1" "8.8.8.8" ];
+      dns = [
+        "1.1.1.1"
+        "8.8.8.8"
+      ];
       log-driver = "journald";
       registry-mirrors = [ "https://mirror.gcr.io" ];
-      storage-driver = "overlay2";
     };
-    # Use the rootless mode
-    rootless = {
-      enable = true;
-      setSocketVariable = true;
-    };
-    # Install docker-compose
-    extraPackages = with pkgs; [
-      docker-compose
-    ];
   };
 }

modules/nixos/drives.nix

@@ -1,47 +0,0 @@
-{ config, lib, pkgs, ... }:
-
-# Add encrypted drives to argon
-
-{
-  # copy keyfiles into initrd to make them available during early boot
-  boot.initrd.secrets = {
-    "/etc/nixos/keys/data1.key" = "/etc/nixos/keys/data1.key";
-    "/etc/nixos/keys/data2.key" = "/etc/nixos/keys/data2.key";
-    "/etc/nixos/keys/nvmecache.key" = "/etc/nixos/keys/nvmecache.key";
-  };
-
-  # decrypt data drives with keyfiles for argon
-  boot.initrd.luks.devices = {
-    "data1" = {
-      device = "/dev/disk/by-uuid/dfae62cc-bad1-4879-bf9a-461bde833625";
-      keyFile = "/etc/nixos/keys/data1.key";
-    };
-    "data2" = {
-      device = "/dev/disk/by-uuid/8312edae-9247-481b-a313-52a7f848f027";
-      keyFile = "/etc/nixos/keys/data2.key";
-    };
-    "nvmecache" = {
-      device = "/dev/disk/by-uuid/2352250e-4ebe-4f9a-bf66-0d4aaa961bd8";
-      keyFile = "/etc/nixos/keys/nvmecache.key";
-    };
-  };
-
-  # mount decrypted filesystems
-  fileSystems."/mnt/data1" = {
-    device = "/dev/mapper/data1";
-    fsType = "ext4";
-    options = [ "nofail" ];
-  };
-
-  fileSystems."/mnt/data2" = {
-    device = "/dev/mapper/data2";
-    fsType = "ext4";
-    options = [ "nofail" ];
-  };
-
-  fileSystems."/mnt/nvmecache" = {
-    device = "/dev/mapper/nvmecache";
-    fsType = "ext4";
-    options = [ "nofail" ];
-  };
-}

modules/nixos/gnupg.nix

@@ -1,15 +1,26 @@
-{ config, lib, pkgs, ... }:
+# A graphical pinentry never grabs the tty, so a passphrase prompt can't take
+# over a terminal driven by a coding agent. The cache lasts a working day, and
+# an unattended signature fails after two minutes instead of blocking forever.
+
+{ config, pkgs, ... }:
 
 {
-  # enable gnupg agent
   programs.gnupg.agent = {
     enable = true;
-    enableSSHSupport = true;
-    pinentryPackage = pkgs.pinentry-curses;
+    pinentryPackage = pkgs.pinentry-qt;
+    settings = {
+      default-cache-ttl = 86400;
+      max-cache-ttl = 86400;
+      pinentry-timeout = 120;
+    };
   };
 
-  environment.systemPackages = with pkgs; [ 
-    gnupg
-    pinentry-curses
+  environment.systemPackages = [
+    pkgs.pinentry-curses # fallback for sessions without a display
+    # prime the passphrase cache on demand, e.g. before an agent session
+    (pkgs.writeShellScriptBin "gpg-unlock" ''
+      echo | ${config.programs.gnupg.package}/bin/gpg --clearsign --output /dev/null
+      echo "gpg key unlocked"
+    '')
   ];
 }

modules/nixos/gnuradio.nix

@@ -1,12 +0,0 @@
-{ config, lib, pkgs, ... }:
-
-{
-  # install gnuradio companion along with it's osmocom library
-  environment.systemPackages = with pkgs; [
-    (gnuradio.override {
-      extraPackages = with gnuradio.pkgs; [ osmosdr ];
-    })
-    gqrx
-    hackrf
-  ];
-}

modules/nixos/graphics.nix

@@ -1,17 +0,0 @@
-{ config, lib, pkgs, ... }:
-
-{
-  # enable amd GPU acceleration (mesa, vulkan, egl)
-  hardware.graphics = {
-    enable = true;
-    enable32Bit = true;
-  };
-
-  # install amdgpu_top
-  environment.systemPackages = with pkgs; [
-    amdgpu_top
-  ];
-  
-  # add amdgpu to the initrd for plymouth
-  hardware.amdgpu.initrd.enable = true;
-}

modules/nixos/greetd.nix

@@ -1,4 +1,4 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
   # greetd display manager with tuigreet

modules/nixos/locales.nix

@@ -1,5 +1,3 @@
-{ config, lib, pkgs, ... }:
-
 {
   # set the time zone
   time.timeZone = "Europe/Zurich";

modules/nixos/networking.nix

@@ -1,20 +1,12 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # user networkmanager
   networking.networkmanager.enable = true;
 
-  # firewall default configs
-  networking.firewall.allowedTCPPorts = [ ];
-  networking.firewall.allowedUDPPorts = [ ];
-
-  # enable wifi firmware
+  # wifi firmware and bluetooth
   hardware.enableAllFirmware = true;
-
-  # enable bluetooth
   hardware.bluetooth.enable = true;
-  
-  # Add network-related packages
+
   environment.systemPackages = with pkgs; [
     wireguard-tools
     update-systemd-resolved

modules/nixos/niri.nix

@@ -1,11 +1,7 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # just enable and install niri
+  # compositor and session; the config itself lives in home-manager
   programs.niri.enable = true;
-
-  # Add compositor-related packages
-  environment.systemPackages = with pkgs; [
-    xwayland-satellite
-  ];
+  environment.systemPackages = [ pkgs.xwayland-satellite ];
 }

modules/nixos/noctalia.nix

@@ -1,12 +1,14 @@
-{ config, lib, pkgs, inputs, ... }:
+{ pkgs, ... }:
+
 {
-  # install noctalia and helper packages
+  # helpers for the noctalia shell (the shell itself comes from home-manager)
   environment.systemPackages = with pkgs; [
-    inputs.noctalia.packages.${pkgs.stdenv.hostPlatform.system}.default
     adw-gtk3
-    adwaita-qt
     adwaita-qt6
     brightnessctl
+    ddcutil
     playerctl
+    wl-clipboard
+    wl-mirror
   ];
 }

modules/nixos/openssh.nix

@@ -1,5 +1,3 @@
-{ config, lib, pkgs, ... }:
-
 {
   # enable the openssh daemon
   services.openssh = {

modules/nixos/packages.nix

@@ -1,9 +1,11 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # system packages
+  # baseline tools for every host
   environment.systemPackages = with pkgs; [
     btop
+    cifs-utils
+    claude-code
     cowsay
     dnsutils
     ethtool
@@ -13,28 +15,23 @@
     imv
     iperf3
     jq
-    kdePackages.qtmultimedia
     ldns
     lm_sensors
     lsof
-    ltrace
     mtr
-    neovim
+    nfs-utils
     nh
     nix-output-monitor
     nmap
-    nvd
     p7zip
     pciutils
     socat
-    sof-firmware
     strace
     sysstat
     tree
     unzip
     usbutils
     vim
-    wl-clipboard
     wget
     which
     xz

modules/nixos/protonvpn.nix

@@ -1,13 +1,8 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # protonvpn uses wireguard tunnels, which break strict reverse path filtering
-  # because packets arrive on the tunnel interface but may be routed back differently.
-  # "loose" checks that the source is routable through *any* interface (not necessarily
-  # the same one), which is sufficient for wireguard while still preventing IP spoofing.
+  # wireguard replies may leave on another interface, so strict rpfilter drops them
   networking.firewall.checkReversePath = "loose";
 
-  environment.systemPackages = with pkgs; [
-    proton-vpn
-  ];
+  environment.systemPackages = [ pkgs.proton-vpn ];
 }

modules/nixos/sddm.nix

@@ -1,25 +1,15 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # enable sddm and use astronaut theme
   services.displayManager.sddm = {
     enable = true;
     wayland.enable = true;
     autoNumlock = true;
     enableHidpi = true;
     theme = "sddm-astronaut-theme";
-    settings = {
-      Theme = {
-        Current = "sddm-astronaut-theme";
-      };
-    };
-    extraPackages = with pkgs; [
-      sddm-astronaut
-    ];
+    extraPackages = [ pkgs.sddm-astronaut ]; # theme's qml dependencies
   };
 
-  # Make the theme available in the system path so sddm can find it
-  environment.systemPackages = with pkgs; [
-    sddm-astronaut
-  ];
+  # sddm looks for themes in the system path
+  environment.systemPackages = [ pkgs.sddm-astronaut ];
 }

modules/nixos/services.nix

@@ -1,5 +1,3 @@
-{ config, lib, pkgs, ... }:
-
 {
   # list of enabled services on the system
   services = {

modules/nixos/settings.nix

@@ -1,30 +1,25 @@
-{ config, lib, pkgs, ... }:
-
 {
   nix = {
-    # nix settings
     settings = {
-      # enable flakes and nix-command
-      experimental-features = [ "nix-command" "flakes" ];
-      # auto-optimize my nix-store
-      auto-optimise-store = true;
-      # use all cores
-      max-jobs = "auto";  
-      # use all available cores per job
-      cores = 0;          
-      # add trusted substituters (binary caches)
-      substituters = [
-        "https://cache.nixos.org"
-        "https://nix-community.cachix.org"
+      experimental-features = [
+        "nix-command"
+        "flakes"
       ];
-      # add keys
-      trusted-public-keys = [
-        "cache.nixos.org-1:6NCHdD59X431o0gWypbMrAURkbJ16ZPMQFGspcDShjY="
+      auto-optimise-store = true;
+      # parallel builds, each using all cores
+      max-jobs = "auto";
+      cores = 0;
+      # cache.nixos.org is the default, these come on top
+      extra-substituters = [ "https://nix-community.cachix.org" ];
+      extra-trusted-public-keys = [
         "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs="
       ];
+      trusted-users = [
+        "root"
+        "@wheel"
+      ];
     };
-    
-    # enable automatic garbage collection
+
     gc = {
       automatic = true;
       dates = "weekly";
@@ -32,14 +27,12 @@
     };
   };
 
-  # allow unfree packages (steam, protonvpn, discord, etc.)
+  # build on disk, big builds would fill the /tmp tmpfs
+  systemd.services.nix-daemon.environment.TMPDIR = "/var/tmp";
+
+  # steam, protonvpn, discord, etc.
   nixpkgs.config.allowUnfree = true;
 
   # links /libexec from derivations to /run/current-system/sw
   environment.pathsToLink = [ "/libexec" ];
-
-  # enable home-manager globally
-  home-manager.useGlobalPkgs = true;
-  home-manager.useUserPackages = true;
-  home-manager.backupCommand = "mv -f {file} {file}.hm-bak-$(date +%Y%m%d%H%M%S)";
 }

modules/nixos/steam.nix

@@ -1,20 +1,13 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # enable steam and open firewall
   programs.steam = {
     enable = true;
+    # fix black screen when running under xwayland-satellite
+    package = pkgs.steam.override { extraArgs = "-system-composer"; };
     remotePlay.openFirewall = true;
     dedicatedServer.openFirewall = true;
     localNetworkGameTransfers.openFirewall = true;
-    # add proton-glorious-eggroll
-    extraCompatPackages = with pkgs; [
-      proton-ge-bin
-    ];
-  };
-
-  # fix black screen in steam when using xwayland-satellite
-  programs.steam.package = pkgs.steam.override {
-    extraArgs = "-system-composer";
+    extraCompatPackages = [ pkgs.proton-ge-bin ];
   };
 }

modules/nixos/thunar.nix

@@ -0,0 +1,9 @@
+{ pkgs, ... }:
+
+{
+  programs.thunar.enable = true;
+
+  # thumbnails: tumbler service plus the path it loads extensions from
+  environment.systemPackages = [ pkgs.tumbler ];
+  environment.pathsToLink = [ "share/thumbnailers" ];
+}

modules/nixos/users.nix

@@ -1,18 +1,16 @@
-{ config, lib, pkgs, ... }:
+{ pkgs, ... }:
 
 {
-  # create users
   users.users.aaron = {
     isNormalUser = true;
-    group = "users";
-    extraGroups = [ "wheel" "networkmanager" "dialout" ];
+    extraGroups = [
+      "wheel"
+      "networkmanager"
+      "dialout"
+    ];
     shell = pkgs.zsh;
   };
 
-  # add default zsh config
-  programs.zsh = {
-    enable = true;
-    enableCompletion = true;
-    autosuggestions.enable = true;
-  };
+  # login shell; plugins and prompt are configured in home-manager
+  programs.zsh.enable = true;
 }

modules/nixos/vial.nix

@@ -0,0 +1,21 @@
+# Vial keyboards (lily58 pro r2g) expose a raw HID interface that vial.rocks
+# drives over WebHID; its /dev/hidraw* node is root-only by default.
+# The rule ships as 60-vial.rules because uaccess is only applied by
+# 73-seat-late.rules, and services.udev.extraRules lands at 99, too late.
+
+{ pkgs, ... }:
+
+{
+  services.udev.packages = [
+    (pkgs.writeTextFile {
+      name = "vial-udev-rules";
+      destination = "/lib/udev/rules.d/60-vial.rules";
+      # the magic serial matches any vial board; uaccess grants the seat owner
+      text = ''
+        KERNEL=="hidraw*", SUBSYSTEM=="hidraw", ATTRS{serial}=="*vial:f64c2b3c*", TAG+="uaccess"
+      '';
+    })
+  ];
+
+  environment.systemPackages = [ pkgs.vial ];
+}

statix.toml

@@ -0,0 +1,8 @@
+# statix configuration (run via `lint` in the devenv)
+
+# Flat assignments like `boot.loader = ...; boot.plymouth = ...;` are the
+# preferred style in this repo, so don't ask for them to be merged.
+disabled = [ "repeated_keys" ]
+
+# Generated by nixos-generate-config, not maintained by hand.
+ignore = [ "hosts/*/hardware-configuration.nix" ]

users/aaron/home.nix

@@ -1,11 +1,11 @@
-{ config, pkgs, ... }:
-
 {
   imports = [
     ../../modules/home-manager/fonts.nix
     ../../modules/home-manager/git.nix
     ../../modules/home-manager/ghostty.nix
     ../../modules/home-manager/nixvim.nix
+    ../../modules/home-manager/niri.nix
+    ../../modules/home-manager/noctalia.nix
     ../../modules/home-manager/programs.nix
     ../../modules/home-manager/shell.nix
     ../../modules/home-manager/styling.nix